Формула с применением функции ЕСЛИ

[baters]

Именно так, я добавил АВС .
Еще раз спасибо.

[vikttur]

Ух и тема. Это же надо, столько муссировать ЕСЛИ()
Самая первая формула

Код Выделить Развернуть

ABS(МИН(A1+B1+C1;))

[baters]

Добрый день.

Помогите дополнить вот эту формулу  =ЕСЛИ(C1>=0;M1;(C1-M1)*(C1>M1)) следующем условием Если М1 больше ноля, то в итоге 0.
Заранее спасибо.

[DV]

Да так и написать:
=ЕСЛИ(M1>0;0;ЕСЛИ(C1>=0;M1;(C1-M1)*(C1>M1)))

[baters]

Работает, спасибо.

[vikttur]

Можно немного причесать:

Код Выделить Развернуть

=ЕСЛИ(M1<0;ЕСЛИ(C1<0;МАКС(C1-M1;);M1);)

[baters]

Добрый день форумчане!

Помогите плиз со следующей формулой (ели она конечно реальна).
Если F6>0 и BF<0 то делается вот это =ЕСЛИ(И(F6>0;BP6<0);F6+BP6;0) если полученный результат  меньше 0, то подставляется 0.
Если F6<0 и BF>0 то делается соответственно вот это =ЕСЛИ(И(F6<0;BP6>0);F6+BP6;0) если полученный результат больше 0, то подставляется 0.
Если F6>0 и BF>0 то подставляется F6
Если F6<0 и BF<0 то подставляется F6

И все эти условия должны быть в одной формуле....мой мозг, не всилах все, это сделать (плиз хелп).

[vikttur]

Нет ошибки?
В условиях BF (BF6?), в вычислениях BP6.

Код Выделить Развернуть

=ЕСЛИ(ЗНАК(F6)=ЗНАК(BF6);F6;ЕСЛИ(F6>0;МАКС(F6+BP6;);МИН(F6+BP6;)))

[baters]

Офигеть.....не формула , а прямо монстр среди формул...она наверно умнее меня будет!
Этож какие грибы, есть нужно, что бы такую штуковину написать!?!? (шутка).
Ну прямотаки огроменно спасибо!
PS а ошибка в наименовании столбца была (спасибо).

[vikttur]

Еще поел грибов

Код Выделить Развернуть

=ЕСЛИ(ЗНАК(F6)=ЗНАК(BP6);F6;(F6+BP6)*(ABS(F6)>ABS(BP6)))
Первая формула быстрее, вторую еще подурнее можно, но грибы кончились

[baters]

Еще раз, сдрасте.

помогите плиз к вот этому =ЕСЛИ(ЗНАК(F6)=ЗНАК(BF6);F6;ЕСЛИ(F6>0;МАКС(F6+BP6;);МИН(F6+BP6;))) добавть еще одно условие, если F6=0, то проставляется 0.

[vikttur]

Код Выделить Развернуть

=ЕСЛИ(F6;формула;)

[baters]

Шикарно....
Большое спасибо.

[vikttur]

baters написал в личку, попросил "разжевать" формулу. Ответить здесь будет правильнее.

Код Выделить Развернуть

=ЕСЛИ(F6;ЕСЛИ(ЗНАК(F6)=ЗНАК(BN6);F6;ЕСЛИ(F6>0;МАКС(F6+BN6;);МИН(F6+BN6;)));)
Сократим для понимания:

Код Выделить Развернуть

=ЕСЛИ(F6;условие_ИСТИНА;)

=ЕСЛИ(F6...;
Такая запись действительна только для числовых данных, для текста применять нельзя, идентична:
ЕСЛИ(F6<>"";... или ЕСЛИ(F6<>0;... - если F6 не равно нулю, то проверяется условие_ИСТИНА, если равно нулю, то ноль (условие_ЛОЖЬ опущено, равнозначно нулю).

Условие_ИСТИНА:

Код Выделить Развернуть

ЕСЛИ(ЗНАК(F6)=ЗНАК(BN6);F6;ЕСЛИ(F6>0;МАКС(F6+BN6;);МИН(F6+BN6;)))
По Вашему условию: «Если F6>0 и BF>0 и если F6<0 и BF<0 то подставляется F6». Это реализовано в условии:
ЕСЛИ(ЗНАК(F6)=ЗНАК(BN6);... - если знаки чисел равны, то проверяется условие истинности (выводится значение F6), при невыполнении условия :

Код Выделить Развернуть

ЕСЛИ(F6>0;МАКС(F6+BN6;);МИН(F6+BN6;))
При F6>0 (уже не может быть BP6>0, т.к. это условие проверялось в предыдущей функции) проверяем Ваше первое условие «=ЕСЛИ(И(F6>0;BP6<0);F6+BP6;0)»:

Код Выделить Развернуть

МАКС(F6+BN6;0)
т.е. если сумма меньше или равна нулю, то ноль.
При F6<0 аналогично:

Код Выделить Развернуть

МИН(F6+BN6;0))

[baters]

Ну очень большое спасибо за разъяснения.