Преобразование формулы из экселя для гугл-таблицы

[Abby]

Добрый день! Прошу помощи, в подборе (исправлении) формулы для гугл-таблиц.

Вводные:
Есть два листа, на первом листе общая таблица (где все заявки, и оттуда ничего не должно удаляться), и второй лист, куда должны дублироваться строки из общей таблицы, где выполнено два условия (исполнено и РД), так как с этими данными уже будут работать другие люди, а их интересуют только исполненные РД, и чтобы не фильтровать общую таблицу, требуется как раз перенос (дублирование) данных на второй лист.
На второй лист должны перенос. только новые строчки (без задвоев, то есть сегодня у меня в общей таблице было 5 строк соответствующих критериям, они дублируются на второй лист, завтра к этим 5 в общей таблице прибавилось еще 6 строк, соответ. критериям, и эти 6 должны продублироваться на вторую вкладку к тем 5, что там уже есть.)

Есть подходящая формула для экселя (в прилож. файле можно посмотреть, что нужно), но она не работает в гугл таблице, помогите пожалуйста поправить. (Возможно дело в функции агрегат, но это не точно).

=ЕСЛИОШИБКА(ИНДЕКС('общая таблица'!A$2:A$30;АГРЕГАТ(15;6;СТРОКА($1:$30)/('общая таблица'!$A$2:$A$30="исполнено")/('общая таблица'!$F$2:$F$30="РД");ЧСТРОК($2:2)));"")

[Дмитрий Щербаков(The_Prist)]

Зачем в Гугл такие сложности? Судя по описанию задачи - здесь достаточно одной функции QUERY. Удаляете все свои формулы из таблицы РД и вместо них в ячейку А2 вводите такую:
=QUERY('общая таблица'!$A$2:$H$30;"SELECT * WHERE A='исполнено' AND F='РД'")

[Abby]

Зачем в Гугл такие сложности? Судя по описанию задачи - здесь достаточно одной функции QUERY. Удаляете все свои формулы из таблицы РД и вместо них в ячейку А2 вводите такую:
=QUERY('общая таблица'!$A$2:$H$30;"SELECT * WHERE A='исполнено' AND F='РД'")

Спасибо! Отличная формула 
Подскажите пожалуйста, можно ли с помощью данной формулы сделать так, чтобы информация сливалась из двух разных листов в один (третий). Каким образом в начале указать, чтобы поиск осуществлялась в двух листах?

[Дмитрий Щербаков(The_Prist)]

Не вопрос, хоть по трем:
=QUERY({'общая таблица'!$A$2:$H$30;'вторая общая таблица'!$A$2:$H$30};"SELECT * WHERE Col1='исполнено' AND Col6='РД'")
Обратите внимание на именование столбцов - при слиянии двух таблиц, надо указывать не заголовки, а краткие имена столбцов, которые назначаются после слияния: Col1, Col2 и т.д.
Кстати, если кол-во строк заранее неизвестно - можно записывать так(без последней строки):
=QUERY({'общая таблица'!$A$2:$H;'другая общая таблица'!$A$2:$H};"SELECT * WHERE Col1='исполнено' AND Col6='РД'")
А если при этом надо еще и чтобы из двух листов только уникальные значения переносились - то просто добавляете функцию UNIQUE:
=UNIQUE( QUERY({'общая таблица'!$A$2:$H;'другая общая таблица'!$A$2:$H};"SELECT * WHERE Col1='исполнено' AND Col6='РД'"))

[Abby]

Не вопрос, хоть по трем:
=QUERY({'общая таблица'!$A$2:$H$30;'вторая общая таблица'!$A$2:$H$30};"SELECT * WHERE Col1='исполнено' AND Col6='РД'")
Обратите внимание на именование столбцов - при слиянии двух таблиц, надо указывать не заголовки, а краткие имена столбцов, которые назначаются после слияния: Col1, Col2 и т.д.
Кстати, если кол-во строк заранее неизвестно - можно записывать так(без последней строки):
=QUERY({'общая таблица'!$A$2:$H;'другая общая таблица'!$A$2:$H};"SELECT * WHERE Col1='исполнено' AND Col6='РД'")
А если при этом надо еще и чтобы из двух листов только уникальные значения переносились - то просто добавляете функцию UNIQUE:
=UNIQUE( QUERY({'общая таблица'!$A$2:$H;'другая общая таблица'!$A$2:$H};"SELECT * WHERE Col1='исполнено' AND Col6='РД'"))

Подскажите пожалуйста, может я что то не так делаю, формула работает, все нужные данные подтягиваются, но почему то названия столбцов на листе, где формула, какие-то кривые, там и название и плюс информация из всего столбика (в одной ячейке). Отчего это может быть. На листах, откуда тянется информация столбики названы одинаково и коротко.

И спасибо большое за помощь! Очень помогли 

[Дмитрий Щербаков(The_Prist)]

может я что то не так делаю

Может. Но по скрину ничего не понятно - лучше приложите ссылку на таблицу Гугл. Я не гадалка и по непонятным числам в ячейке не умею диагностировать причины ошибок функций и таблиц 

столбики названы одинаково и коротко

это не важно - я же написал, что при объединении двух таблиц надо указывать Col1, Col2 и т.д. Это стандартное именование при объединении нескольких таблиц в функции Query. При этом то, как названы сами столбцы таблицы вообще неважно.