1. Прикрепить файл.
2. На sql.ru не просто "есть проще решение. всем спасибо", а описание этого решения - не Вам одному может понадобиться.

И все кинулись рисовать счет-фактуру и данные...

Если еще надумаете ЕСЛИ(), то лучше создавать новые темы: функция одна, но задачи-то разные  и часто решаются с помощью других функций.

В фигурные скобки можно заключать значения констант, с переменными фокус не проходит.

Так и пишите:

Код:

ЕСЛИ(И(L6>0;N6>0);1;ЕСЛИ(И(L6>0;N6=0);2;ЕСЛИ(И(L6=0;N6>0);3;ЕСЛИ(И(L6<0;N6<>0);4;"больше данных нет"))))

Можно поиграться, если выложите полный список условий.

Не могли 10 минут подождать?

Глянул: ответ дан в течение 11 минут

Не могли 10 минут подождать?
Ответ на Планете.

После стационарного лечения:
вырезаны доброкачественные опухоли I1:K6, M1:P6, вставлены на другой лист и сшиты в один диапазон;
убрано искривление (сколиоз) первого диапазона вставкой незаполненной полости;
для удобства поиска сделана запись в карточку (имя диапазона посмотреть Ctrl+F3).

После завершения хирургического лечения проведена терапия столбца R для устранения отторжения и полного лечения формульной избыточности:

Код:

=ЕСЛИ(Q12="";"";Q12/ВПР(A12;табл;4;))

Проведено удаление лишних символов в столбце S:

Код:

=ЕСЛИ(Q12="";"";"Прайс-лист "&I12&" от "&ТЕКСТ(H12;"дд.ММ.ГГГГ"))

Состояние пациента после выписки (см. вложение) удовлетворительное, при соблюдении режима пользования стабильное, возможно улучшение здоровья при изменении структуры таблицы.

Химический состав некоторых препаратов.

Отрава, которой потчевали пациента (столбец Т):

Код:

=ЕСЛИ(J12<>0;"текст1")+ЕСЛИ(K12<>0;"текст2")…

При отсутствии значений в ячейках токсического воздействия нет: ЛОЖЬ+ЛОЖЬ=0. Но попытка суммировать текстовые данные приводит к поражению вычислительной способности. Проверьте препараты слабого воздействия и убедитесь в этом:
=0+1; =0+"яд"; ="яд"+"отрава"
Правильнее было бы

Код:

=ЕСЛИ(J12<>0;"текст1";ЕСЛИ(K12<>0;"текст2"…))))))

Не токсично, но длинно.

Столбец Q: если сумма больше нуля, то выполняется поиск метода вычислений:

Код:

ВЫБОР(номер_индекса;формула1;формула2;формула3;...)

номер_индекса=ПОИСКПОЗ(9E+307;J12:P12;1) – определяет позицию ненулевого значения в диапазоне, по этому номеру ВЫБОР() ищет формулу.

В столбце Т практически то же лекарство, только формулы заменены рецептами.

Сумеречное помрачение сознания лечилось простым народным средством (столбец S):

Код:

ТЕКСТ(H12;"дд.ММ.ГГГГ")

Пациент поступил с жалобами на отказ работы формул в районе столбца Т и постоянные кошмарные видения при обращении к столбцу S.

Основной Д-з: расшифровочная недостаточность, вызванная неправильным применением препарата ЕСЛИ(), сумеречное помрачение сознания с наплывом галлюцинаций устрашающего содержания (преимущественно зрительных).

Сопутствующий Д-з: формульная переизбыточность средней тяжести, легкая недостаточность вычислений в столбце А, сколиоз вспомогательных таблиц.

Экстренное лечение патологий:
- аккуратное введение формулы внутриячеечно в Т12 и S12 с последующим принятием болеутоляющего (копирование ячейки вниз по 3-4 строки 1 раз в секунду):

Код:

=ЕСЛИ(Q12="";"";ВЫБОР(ПОИСКПОЗ(9E+307;J12:P12;1);J12&"/1,18";K12&"*"&$G$2&"*1,03/1,18";L12&"*"&$G$2&"/1,18";M12&"*"&$G$3&"/1,18";N12;O12&"*"&$G$2;P12&"*"&$G$3))
=ЕСЛИ(Q12="";"";"Прайс-лист"&" "&I12&" "&"от"&" "&ТЕКСТ(H12;"дд.ММ.ГГГГ"))

- вытравливание формул в столбцах Q и R с последующим введением новых препаратов:

Код:

=ЕСЛИ(СУММ(J12:P12);ВЫБОР(ПОИСКПОЗ(9E+307;J12:P12;1);J12/1,18;K12*$G$2*1,03/1,18;L12*$G$2/1,18;M12*$G$3/1,18;N12;O12*$G$2;P12*$G$3);"")
=ЕСЛИ(Q12="";"";Q12/ВПР(A12;ИНДЕКС(($I$2:$K$6;$M$2:$P$6);;;1+ЕЧИСЛО(ПОИСК("М";A12)));3+ЕЧИСЛО(ПОИСК("М";A12));))

Патологии сопутствующего диагноза в экстренном лечении не нуждаются, но нужна диспансеризация (при отсутствии лечения  возможен переход в хроническую стадию).
Можно пройти курс расчетной терапии, после которого в столбце А будет автоматически просчитываться номер квартала. Но для этого нужна подготовка и информация о принадлежности данных к материалам или оборудованию.
Лечение сколиоза таблиц требует хирургического вмешательства.

Назначено повторное посещение врача.
Прием закончен,  доктора ждут другие пациенты.

Код:

=НАИМЕНЬШИЙ(ЕСЛИ(D6:D15;СТРОКА(6:15)-6);СТРОКА(D1:ИНДЕКС(D1:D15;СЧЁТ(D6:D15))))

Эта формула отбирает только значения (номера строк) из массива:

Код:

ЕСЛИ(D6:D15;СТРОКА(6:15)-6)

Формируем массив значений:

Код:

=Ч(СМЕЩ(D6:D15;НАИМЕНЬШИЙ(ЕСЛИ(D6:D15;СТРОКА(6:15)-6);СТРОКА(D1:ИНДЕКС(D1:D15;СЧЁТ(D6:D15))));))

Если порядок значений неважен или значения расположены всегда в возрастающем порядке:

Код:

=НАИМЕНЬШИЙ(ЕСЛИ(D6:D15;D6:D15);СТРОКА(D1:ИНДЕКС(D1:D15;СЧЁТ(D6:D15))))

Поторопился, что всё работает.

Диапазон значений {10000:0:0:100000} (4 значения), Вы задаете  КПЕР=5. Может быть, здесь проблема?
Я не разбирался в работе функции.

В предыдущем сообщении формула разбита: показано начало диапазона и его конец.
начало:конец - такая запись создает диапазон.

эта конструкция выводит только одно значения массива D6:D15

В ячейке вы видите только одно значение, но Excel видит весь диапазон.
Выделите формулу диапазона в строке формул и нажмите F9 ("Вычислить"). Вместо формулы диапазона увидите результат ее работы - диапазон значений.

...после применения фильтра на листе1... на лист2 появлется ссылка...

Лист1 в примере пустой, Лист2 - нет такого.
Похоже, чего-то хотите от листа "Дефектная". Заполните не одну, а несколько строк и покажите, что не получается.

Диапазон значений от

Код:

ИНДЕКС(D6:D15;ПОИСКПОЗ(1=1;D6:D15>0;))

до

Код:

ИНДЕКС(D6:D15;ПОИСКПОЗ(9E+307;D6:D15;1))

Формула массива С6 с динамичным диапазоном:

Код:

=СУММ(ПЛТ(B6/12;{4:5}*12;0;-ИНДЕКС(D6:D15;ПОИСКПОЗ(1=1;D6:D15>0;)):ИНДЕКС(D6:D15;ПОИСКПОЗ(9E+307;D6:D15;1))))