Excel это не сложно

Здравствуйте!
Суть вопроса такая, есть столбец, в нем значения в некоторых ячейках по одному, в некоторых по два, в некоторых через тире. Все эти значения которые надо подставить в отдельный столбец по одному, причем значения с тире надо раскрыть это по сути границы диапазона. Вид примерно такой C430-C435 первого столбца надо вносить значения вида С430 С431 С342 и т.д. Знаю это можно сделать в Power Query, но как именно?

Вероятно, можно сделать так:

let
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Что есть", type text}}),
    replace = Text.Replace(
            Text.Replace(
                Text.Replace(
                    Text.Replace(Text.Combine(Source[Что есть],","),"C","")
                    ,"-","..")
                ,",,",",")
            ," ",""),
    split = Text.Split(replace,","),
    res = List.Transform(List.Union(List.Transform(split, each 
            if Text.Contains(_,"..") then List.Numbers(
                        Number.FromText(Text.Split(_,".."){0}),
                                        Number.FromText(Text.Split(_,".."){1}) - Number.FromText(Text.Split(_,".."){0}) + 1)
            else {_})
    ), each "C" & Text.From(_))
in
    res

Еще вариант

// Таблица1
let
    Source = List.RemoveMatchingItems(Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content][Столбец1],{null}),
    Custom1 = List.Transform(Source, each 
                                          let 
                                              i=Text.Trim(_,{",","C"}) 
                                          in 
                                              if Text.Contains(i,"-") 
                                              then 
                                                    let 
                                                        ii=Text.Split(i,"-C") 
                                                    in {Number.From(ii{0})..Number.From(ii{1})} 
                                              else Text.Split(i,", C")),
    Custom2 = List.Transform(List.Combine(Custom1), each "C"&Text.From(_))
in
    Custom2

Большое спасибо! Помогло!

Большое спасибо! Тоже воспользовался  :)