Забыли пароль?


Хитрости »
Основные понятия (23)
Сводные таблицы и анализ данных (9)
Графики и диаграммы (5)
Работа с VB проектом (12)
Power BI и Power Query (16)
Условное форматирование (5)
Списки и диапазоны (5)
Макросы(VBA процедуры) (63)
Разное (39)
Баги и глюки Excel (3)

Ведение журнала сделанных в книге изменений

Проблема очень актуальна для больших организаций, когда одним файлом пользуются несколько человек. И каждый может сделать какие-то свои изменения. И конечно всегда наступает момент когда надо узнать - а кто сделал то или иное изменение? Возможно просто для информации, а бывает и хуже, когда необходимо узнать кто внес конкретное изменение, которое делать было нельзя и по возможности восстановить хоть часть того, что было.


Отслеживание изменений при помощи встроенных средств - Общий доступ к книге
Есть относительно простой способ отслеживать изменения(если это можно так назвать): дать книге общий доступ
Excel 2007 и выше: вкладка Рецензирование(Review) -Доступ к книге(Share workbook). В появившемся окне поставить галочку разрешить изменять файл нескольким пользователям одновременно(Allow changes by more then one user at the same time):
Доступ к файлу
Далее можно настроить срок хранения лога изменений, конфликты и пр - вкладка Подробнее(Advanced):
Параметры доступа
Регистрация изменений(Track changes)

  • Хранить журнал в течение(keep change history for): - если необходимо вести журнал изменений(а нам необходимо!) то оставляем этот пункт включенным и устанавливаем количество дней, в течение которых необходимо сохранять историю. По умолчанию это 30 дней. Здесь имеются ввиду последние 30 дней от текущей даты. Т.е. по истечению этих 30 дней более ранние данные истории будут затерты
  • Не хранить журнал изменений(don't keep change history): после выбора этого пункта и подтверждения журнал будет удален(если он был создан) и история вестись не будет

Обновлять изменения

  • При сохранении файла(When file is saved) - это самый оптимальный вариант. Данные об изменениях в файле будут обновляться только тогда, когда мы сами сохраним файл.
  • Каждые(Automatically every): указывается промежуток времени в минутах, через который книга сама автоматически будет сохраняться и регистрировать изменения. Не очень удобен данный пункт если в файле одновременно работает несколько человек. При этом необходимо будет обязательно выбрать какое действие будет производится по умолчанию:
    • сохранить мои изменения и просмотреть чужие(save my changes and see others' changes)
    • только просмотреть чужие изменения(just see other users' changes)

    Пункты говорят сами за себя, можно отметить лишь один нюанс: принимать решение о сохранении тех или иных изменениях будет тот пользователь, который первым открыл файл.

Для противоречивых изменений(Conflicting changes between users)

    данный пункт управляет разрешением конфликтов, если при одновременном пользовании файлом несколькими пользователями два и более пользователя сделали изменения в одной и той же ячейке листа.

  • запрашивать чьи изменения имеют преимущество(ask me which changes win) - самый оптимальный вариант. Первый, открывший файл пользователь определяет какие изменения надо принять, а какие отклонить
  • ранее сохраненные имеют преимущество(the changes being saving win) - не очень правильный вариант, но все зависит от ситуации. По логике при данном пункте при возникновении конфликта автоматически будут приняты лишь те изменения, которые были сделаны ранее. Может сыграть нехорошую шутку, поэтому надо быть острожным с этим пунктом

Включить в личное представление(Include in personal view)

    Данный пункт управляет настройками печати и фильтра общей книги для нескольких пользователей.

  • параметры печати(Print settings) - Обычно, в одном файле когда мы настраиваем параметры печати, они сохраняются внутри файла и при следующем открытии их не надо уже заново настраивать. Здесь тоже самое, но хранится для каждого пользователя отдельно. Т.е. даже если в этом файле один пользователь настроил одни параметры печати, а другой – иные, то для каждого пользователя эти параметры сохраняться. В обычной книге применились бы те параметры, которые были назначены перед последним сохранением книги.
  • фильтры(Filter settings) - если один пользователь отфильтровал данные по "Юго-Восточный округ", а другой тот же столбец по "Северный округ", то при установленном данном пункте у каждого пользователя файл откроется с отфильтрованными строками именно по установленным ими параметрам - для каждого свой
  • Но оба эти пункта имеют большой недостаток: в зависимости от количества пользователей и их действий они могут сильно "раздувать" файл и приводить к значительным его "тормозам". Поэтому без необходимости лучше их не использовать

Теперь самое главное: как увидеть все сделанные изменения
После того, как пользователи поработали с файлом и стало необходимо увидеть сделанные изменения необходимо перейти на вкладке Рецензирование(Review) -Исправления(Track changes) -Выделить исправления(Highlight changes)
Просмотреть изменения
Здесь можно выбрать какие изменения показывать

  • по времени(When) - если хотите увидеть только какие-то конкретные изменения, то надо установить галочку на этом пункте и выбрать нужное. Доступно выбрать: Со времени последнего сохранения, Все, Еще не просмотрено, С даты. Пункты достаточно красноречивы и понятны, расписывать каждый не вижу смысла. Если хотите просмотреть все изменения - галочку с этого пункта надо снять
  • пользователем(Who) можно показать изменения, сделанные конкретным пользователем, всеми пользователями, или всеми пользователями, кроме того, кто запросил отчет об изменениях(т.е. кроме себя любимого)
  • в диапазоне(Where) можно указать конкретный диапазон на листе и отчет об изменения будет выведен только для ячеек этого диапазона.

Выделять исправления на экране(Highlight changes on screen): если установить эту галочку, то изменения будут созданы в виде примечаний к ячейкам, изменения в которых были сделаны. В левом верхнем углу ячейки в этом случае появится черный треугольник, а при наведении на эту ячейку появится примечание с информацией о том кто изменил, когда и на что:
Изменения в примечании

Вносить изменения на отдельный лист(List changes on a new sheet): в этом случае будет создан новый лист с именем "Журнал", в котором будут перечислены ячейки, в которые были внесены изменения с указанием даты и времени изменения, пользователя сделавшего изменение, старое и новое значение измененной ячейки:
Изменения в отдельном листе

Примечание: После того, как книге дан общий доступ книгу одновременно могут менять несколько пользователей. Однако я не рекомендую делать это без крайней необходимости, т.к. одновременный доступ к файлам Excel реализован очень плохо и работает это нестабильно. В какой-то момент файл может просто отказаться работать и все данные будут утеряны. Так же неизбежно будут возникать спорные ситуации, когда изменения внесли два человека одновременно и не сохранилось в результате ни одно из внесенных.

Но самый главный недостаток: книги в общем доступе имеют ряд ограничений, среди которых такие как:

  • невозможно удалять листы
  • невозможно создавать диаграммы, можно лишь просматривать созданные ранее
  • невозможно создавать сводные таблицы, можно лишь просматривать созданные ранее
  • невозможно создавать или изменять группировку данных, можно использовать ранее созданную
  • невозможно изменять параметры защиты листов и книги
  • невозможно использовать расширенный фильтр
  • невозможно использовать Текст по столбцам
  • невозможно создавать новые проверки данных, а так же изменять существующие. Допускается лишь обвести или удалить обводку с неверных данных
  • невозможно добавлять или изменять ранее созданные формулы массива
  • и т.д.

Плюс невозможно не только использовать умные таблицы, но и сделать книгу общей, если в ней есть хоть одна умная таблица. Если будет попытка сделать общий доступ к книге с умной таблицей Excel покажет предупреждение, что этого делать нельзя и проинструктирует как преобразовать такую таблицу в диапазон для возможности использовать общий доступ.
Так же хочу отметить, что есть распространенное заблуждение о невозможности использования макросов в книгах с общим доступом. Это не так, коды Visual Basic for Applications разрешается применять и в большинстве случаев они будут работать корректно и как задумывались, если они только не пытаются произвести действия, перечисленные как запрещенные для книг с общим доступом. Плюс невозможно просматривать и изменять коды в книгах с общим доступом.



 
Отслеживание изменений и ведение журнала при помощи кода
Изменения можно отслеживать и при помощи кода. При этом такой метод дает не менее полное представление об изменениях в ячейках и при этом давать общий доступ книге нет необходимости, а следовательно и все ограничения, применимые для книг в общем доступе тоже остаются за бортом, что делает такой подход порой предпочтительнее. Единственное, при таком режиме файл нельзя будет редактировать одновременно нескольким пользователям. Но в большинстве случаев этого и не надо.
Я могу предложить небольшой код, который будет отслеживать следующие параметры:

  • Имя пользователя(учетная запись пользователя на компьютере), сделавшего изменения
  • адрес ячейки, в которую были внесены изменения
  • дата и время внесения изменений
  • имя листа, в котором были сделаны изменения
  • значение ячейки до изменения(старое значение)
  • значение ячейки после изменения(новое значение).

Итак, Вы решили реализовать данный процесс. Изначально необходимо разрешить макросы, без этого данный способ ведения журнала не сработает. Далее необходимо добавить в книгу новый лист с именем LOG и вставить приведенный код в модуль книги, изменения в которойнеобходимо отслеживать:

Option Explicit
Public sValue As String
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If Sh.Name = "LOG" Then Exit Sub
    Dim sLastValue As String
    Dim lLastRow As Long
 
    With Sheets("LOG")
        lLastRow = .Cells.SpecialCells(xlLastCell).Row + 1
        If lLastRow = Rows.Count Then Exit Sub
        Application.ScreenUpdating = False: Application.EnableEvents = False
        .Cells(lLastRow, 1) = CreateObject("wscript.network").UserName
        .Cells(lLastRow, 2) = Target.Address(0, 0)
        .Cells(lLastRow, 3) = Format(Now, "dd.mm.yyyy HH:MM:SS")
        .Cells(lLastRow, 4) = Sh.Name
        .Cells(lLastRow, 5).NumberFormat = "@"
        .Cells(lLastRow, 5) = sValue
        If Target.Count > 1 Then
            Dim rCell As Range, rRng As Range
            On Error Resume Next
            Set rRng = Intersect(Target, Sh.UsedRange): On Error GoTo 0
            If Not rRng Is Nothing Then
                For Each rCell In rRng
                    If Not IsError(Target) Then sLastValue = sLastValue & "," & rCell Else sLastValue = sLastValue & "," & "Err"
                Next rCell
                sLastValue = Mid(sLastValue, 2)
            Else
                sLastValue = ""
            End If
        Else
            If Not IsError(Target) Then sLastValue = Target.Value Else sLastValue = "Err"
        End If
        .Cells(lLastRow, 6).NumberFormat = "@"
        .Cells(lLastRow, 6) = sLastValue
    End With
    Application.ScreenUpdating = True: Application.EnableEvents = True
End Sub
 
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    If Sh.Name = "LOG" Then Exit Sub
    If Target.Count > 1 Then
        Dim rCell As Range, rRng As Range
        On Error Resume Next
        Set rRng = Intersect(Target, Sh.UsedRange): On Error GoTo 0
        If rRng Is Nothing Then Exit Sub
        For Each rCell In rRng
            If Not IsError(rCell) Then sValue = sValue & "," & rCell Else sValue = sValue & "," & "Err"
        Next rCell
        sValue = Mid(sValue, 2)
    Else
        If Not IsError(Target) Then sValue = Target.Value Else sValue = "Err"
    End If
End Sub

Что такое модуль книги и как туда вставить код подробно описано в этой статье. Если кратко: открываем редактор VBA(Alt+F11) -находим в списке объектов ЭтаКнига(ThisWorkbook) -двойной щелчок по ней и в окно редактора справа вставляется этот код.

Лист "LOG" рекомендую сделать скрытым, иначе смысла в отслеживании действий мало, т.к. любой сможет перейти на этот лист и стереть историю своих изменений. Надежно скрыть лист поможет эта статья: Как сделать лист очень скрытым.


Для того, чтобы хранить историю изменений в отдельном текстовом файле или отдельной книге Excel можно применить такой код:

Option Explicit
Public sValue As String
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If Sh.Name = "LOG" Then Exit Sub
    Dim sLastValue As String
    Dim lLastRow As Long, wbLOG As Workbook
    Dim sPath as String
    Const sLOGName As String = "\LOG.txt" '"\LOG.xls"
    sPath = Application.DefaultFilePath
    Application.ScreenUpdating = False
    '==============   только для записи в текстовый файл   ======================
    If Dir(sPath & sLOGName, vbDirectory) = "" Then
        Open sPath & sLOGName For Output As #1: Close #1
    End If
    '==============   только для записи в отдельный файл Excel ======================
'    If Dir(sPath & sLOGName, vbDirectory) = "" Then
'        Set wbLOG = Workbooks.Add
'        wbLOG.SaveAs sPath & sLOGName, xlNormal
'    End If
    Set wbLOG = Workbooks.Open(sPath & sLOGName)
    '============================================================================
    With wbLOG.Sheets(1)
        lLastRow = .Cells.SpecialCells(xlLastCell).Row + 1
        If lLastRow = .Rows.Count Then Exit Sub
        Application.ScreenUpdating = False: Application.EnableEvents = False
        .Cells(lLastRow, 1) = CreateObject("wscript.network").UserName
        .Cells(lLastRow, 2) = Target.Address(0, 0)
        .Cells(lLastRow, 3) = Format(Now, "dd.mm.yyyy HH:MM:SS")
        .Cells(lLastRow, 4) = Sh.Name
        .Cells(lLastRow, 5).NumberFormat = "@"
        .Cells(lLastRow, 5) = sValue
        If Target.Count > 1 Then
            Dim rCell As Range, rRng As Range
            On Error Resume Next
            Set rRng = Intersect(Target, Sh.UsedRange): On Error GoTo 0
            If Not rRng Is Nothing Then
                For Each rCell In rRng
                    If Not IsError(Target) Then sLastValue = sLastValue & "," & rCell Else sLastValue = sLastValue & "," & "Err"
                Next rCell
                sLastValue = Mid(sLastValue, 2)
            Else
                sLastValue = ""
            End If
        Else
            If Not IsError(Target) Then sLastValue = Target.Value Else sLastValue = "Err"
        End If
        .Cells(lLastRow, 6).NumberFormat = "@"
        .Cells(lLastRow, 6) = sLastValue
    End With
    wbLOG.Close 1
    Application.ScreenUpdating = True: Application.EnableEvents = True
End Sub
 
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    If Sh.Name = "LOG" Then Exit Sub
    If Target.Count > 1 Then
        Dim rCell As Range, rRng As Range
        On Error Resume Next
        Set rRng = Intersect(Target, Sh.UsedRange): On Error GoTo 0
        If rRng Is Nothing Then Exit Sub
        For Each rCell In rRng
            If Not IsError(rCell) Then sValue = sValue & "," & rCell Else sValue = sValue & "," & "Err"
        Next rCell
        sValue = Mid(sValue, 2)
    Else
        If Not IsError(Target) Then sValue = Target.Value Else sValue = "Err"
    End If
End Sub

Файл хранится в папке "Мои документы" пользователя. Имя файла - LOG.txt задается посредством константыConst sLOGName As String = "\LOG.txt"

Чтобы вести изменения в отдельной книге Excel надо будет всего лишь закомментировать строки под "только для записи в текстовый файл" и раскомментировать строки под "только для записи в отдельный файл Excel" и поменять значение для константыConst sLOGName As String = "\LOG.xls"
Не следует оставлять оба этих блока - они противоречат друг другу и если оставить оба, то будет создан текстовый файл, но изменения все равно будут заноситься в отдельную книгу Excel.
Если хотите, чтобы файл с историей изменений хранился в папке, отличной от Мои документы, то необходимо
Application.DefaultFilePath заменить на нужный путь, к примеру такой:sPath = "C:\Users\The_Prist\Рабочий стол"

При изменении данного параметра необходимо учитывать, что не у всех пользователей может быть доступ к конкретной папке.

Скачать пример

  Tips_Macro_LOG.xls (50,0 KiB, 6 269 скачиваний)

Так же см.:
Выделение сделанных изменений
Запись изменений на листе в примечания


Статья помогла? Поделись ссылкой с друзьями!
  Плейлист   Видеоуроки

Поиск по меткам

Access apple watch Multex Outlook Power Query и Power BI VBA работа в редакторе VBA управление кодами Бесплатные надстройки Дата и время Диаграммы и графики Записки Защита данных Интернет Картинки и объекты Листы и книги Макросы и VBA Надстройки Настройка Печать Поиск данных Политика Конфиденциальности Почта Программы Работа с приложениями Работа с файлами Разработка приложений Сводные таблицы Списки Тренинги и вебинары Финансовые Форматирование Формулы и функции Функции Excel Функции VBA Ячейки и диапазоны акции MulTEx анализ данных баги и глюки в Excel ссылки
Обсуждение: 142 комментария
  1. Антон:

    Добрый день. А чтобы не создавалась новая строка. А была проверка вносились ли изменения в эту ячейку. Если да то перезаписывало строку иначе создаст новую.

  2. Оксана Ж.:

    Выдает ошибку когда оба текста вставила в модуль
    Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If Sh.Name = "LOG" Then Exit Sub

  3. Grigoriy:

    Здравствуйте Дмитрий!
    Кодом ведения лог.txt файла пользуюсь давно. Всё устраивало до сегодня. Вдруг код стал вызывать ошибку в excel. Что мне удалось уловить. Если открыт 1 файл в котором код ведения лог.txt то всё работает без проблем. Но если открыть ещё файл excel (без кода ведения лог.txt), то при работе с первым файлом в момент работы кода вызывает ошибку в excel на строке –
    Set wbLOG = Workbooks.Open(sPath & sLOGName)
    Ну и сам вопрос, как исправить код?
    Спасибо!

  4. Гоша:

    Здравствуйте! Спасибо за Ваш очень нужный макрос!
    Скажите, пожалуйста, как можно внести данные обновления для него:
    1. запись по заливке ячейки
    2. запись по добавлению примечания в ячейку
    3. запись только последних 100 изменений

    Еще раз огромное спасибо!

    • 1. Никак(Excel не дает возможности из VBA отследить событие изменения форматов ячейки)
      2. Тоже, что и с п.1
      3. Можно, но сразу вопрос: а что есть последние 100? И что делать, когда их станет 101? Смещать весь лог на строку выше?

      • Гоша:

        Да хоть что. Как проще для Вас. Лишь бы сохранялись данные последних ста событий.
        А можно ли добавить к этому макросу еще и данные о пользователях последними сохранявшими документ?
        Спасибо

        • Гоша:

          Как можно сделать последние 100 записей? Ответьте, пожалуйста, срочно нужно.

  5. Гоша:

    и о пользователях сохранивших документ! Пожалуйста!

    • Гоша, если Вам срочно нужно не значит, что я брошу все и буду сидеть и пожелания Ваши исполнять так же срочно. Будет у меня время на доработку нужную ИМЕННО ВАМ - сделаю. В противном случае обращайтесь в личную почту на платной основе.

  6. Дмитрий:

    Спасибо за хороший макрос! Подскажите, как можно реализовать корректно учёт в LOG удалённой строку целиком. Сейчас в лог прописываются данные с кучей запятых. Можно ли учитывать только данные из определённого столбца удалённой строки: например, когда в третьем столбце всей таблицы прописан какой то идентификатор изделия - его и учитывать в файле LOG

  7. Дмитрий:

    Здравствуйте Дмитрий, подскажите пожалуйста: каким образом указать в коде макроса не учитывать в LOGS номер определённого столбца?

    • После строк:

      Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
          If Sh.Name = "LOG" Then Exit Sub

      дописать:

          If Target.Column = 3 Then Exit Sub

      3 - номер столбца, изменения в котором не надо отслеживать.

  8. Keks:

    Дмитрий а у меня вопрос, как можно сделать так что бы работал откат действия Ctrl+Z получается если внез изменение и нужно его отменить то отменить то уже не получится ?

    • Keks, самый простой вариант: перейти в раздел Хитрости и найти там статью "Как отменить действия макроса". Не ленитесь сначала хотя бы названия статей читать, а потом уже вопросы сыпать :-)

  9. Гоша:

    Еще раз вынужден обратиться. Не могу сам разобраться.
    Скажите, пожалуйста, как сделать чтобы работали в одной книге 3 макроса:
    1) Этот самый,
    2) "КАК ЗАПУСТИТЬ ФАЙЛ С ВКЛЮЧЕННЫМИ МАКРОСАМИ?" Вариант 1 (http://www.excel-vba.ru/chto-umeet-excel/kak-zapustit-fajl-s-vklyuchennymi-makrosami/)
    3)и макрос когда и кто последний сохранял документ:
    Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    ThisWorkbook.Worksheets(1).Range("A1") = Now
    ThisWorkbook.Worksheets(1).Range("B1") = Environ("USERNAME")
    End Sub

    Все работает, но выдает ошибку при закрытии файла на строку With wbLOG.Sheets(1)

    Спасибо!

  10. Александр Медведев:

    Добрый день, Дмитирий.
    Используя ваш макрос (ВЕДЕНИЕ ЖУРНАЛА СДЕЛАННЫХ В КНИГЕ ИЗМЕНЕНИЙ) столкнулся с такой особенностью.
    Когда макрос отлавливает повторные изменения в рядом стоящих объединенных ячейках (в моем случае по вертикали), в старое значение ячейки прописывается много лишних символов и такое впечатление что и история предыдущих изменений в смежных объединенных ячейках.
    Пытался вначале подправить код, потом разными способами убрать лишнюю информацию, но все равно нормально не получается. Пока отказался от старых значений и использую только новые.
    Насколько сложно сделать чтобы изменения и в объединенных ячейках корректно регистрировались?
    Спасибо.

Поделитесь своим мнением

Комментарии, не имеющие отношения к комментируемой статье, могут быть удалены без уведомления и объяснения причин. Если есть вопрос по личной проблеме - добро пожаловать на Форум


Для оформления сообщений Вы можете использовать следующие тэги:
<a href="" title=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <q cite=""> <s> <strike> <strong>

Тренинги

Заказать
Юридическая информация

Использование материалов сайта

Политика Конфиденциальности

ИП Щербаков Дмитрий Валентинович
ОГРНИП: 318502700083307
ИНН: 504013350772

Наши партнеры

Перейти
Перейти

Счетчики

Рейтинг@Mail.ru Яндекс.Метрика
© 2019 Excel для всех   Войти