Lost your password?


Хитрости »
Основные понятия (27)
Сводные таблицы и анализ данных (10)
Графики и диаграммы (5)
Работа с VB проектом (12)
Power BI и Power Query (23)
Условное форматирование (5)
Списки и диапазоны (5)
Макросы(VBA процедуры) (68)
Разное (43)
Баги и глюки Excel (5)

Как из Excel обратиться к другому приложению

Иногда бывает необходимо перенести что-то из Excel в другое приложение. Я возьму для примера Word. Например скопировать ячейки и вставить. Обычно мы это так и делаем - скопировали в Excel, открыли Word - вставили. Но сделать это при помощи кода чуть сложнее, хотя если разобраться никаких сложностей нет. Ниже приведен пример кода, который открывает Word, открывает в нем определенный документ, копирует данные из Excel и вставляет в открытый документ Word.

Sub OpenWord()
    Dim objWrdApp As Object, objWrdDoc As Object
    'создаем новое приложение Word
    Set objWrdApp = CreateObject("Word.Application")
    'Можно так же сделать приложение Word видимым. По умолчанию открывается в скрытом режиме
    'objWrdApp.Visible = True
    'открываем документ Word - документ "Doc1.doc" должен существовать
    Set objWrdDoc = objWrdApp.Documents.Open("C:\Doc1.doc")
    'Копируем из Excel диапазон "A1:A10"
    Range("A1:A10").Copy
    'вставляем скопированные ячейки в Word - в начала документа
    objWrdDoc.Range(0).Paste
    'закрываем документ Word с сохранением
    objWrdDoc.Close True    ' False - без сохранения
    'закрываем приложение Word - обязательно!
    objWrdApp.Quit
    'очищаем переменные Word - обязательно!
    Set objWrdDoc = Nothing: Set objWrdApp = Nothing
End Sub

Скачать пример:

  Tips_Macro_OpenWord.xls (49,5 KiB, 6 706 скачиваний)


В файле-примере, приложенном к данной статье, в комментариях к коду есть несколько добавлений. Например, как вставить текст из ячеек в определенные закладки Word-а и как добавить новый документ, а не открывать уже имеющийся. Так же так есть код проверки - открыто ли приложение Word в данный момент. Порой это тоже может пригодиться, чтобы работать с запущенным приложением Word, а не создавать новое:

Sub Check_OpenWord()
    Dim objWrdApp As Object
    On Error Resume Next
    'пытаемся подключится к объекту Word
    Set objWrdApp = GetObject(, "Word.Application")
    If objWrdApp Is Nothing Then
        'если приложение закрыто - создаем новый экземпляр
        Set objWrdApp = CreateObject("Word.Application")
        'делаем приложение видимым. По умолчанию открывается в скрытом режиме
        objWrdApp.Visible = True
    Else
        'приложение открыто - выдаем сообщение
        MsgBox "Приложение Word уже открыто", vbInformation, "Check_OpenWord"
    End If
End Sub

В принципе, активировать или вызвать(если закрыто) другое приложение Офиса можно одной строкой:

Sub Open_AnotherApp()
    Application.ActivateMicrosoftApp xlMicrosoftWord
End Sub

но данный метод может пригодиться только в том случае, если Вам необходимо действительно лишь активировать другое приложение, но дальше обращаться к этому приложению Вы уже не сможете.

По сути, методами CreateObject и GetObject можно обратиться к любому стороннему приложению(например Internet Explorer). Куда важнее при обращении к этим объектам знать объектную модель того приложения, к которому обращаетесь. Чтобы увидеть свойства и методы объектной модели приложения, можно в редакторе VBA подключить необходимую библиотеку, объявить переменную, назначив ей тип приложения. Покажу на примере того же Word-а.
Для начала открываем меню Tools -References:

Подключаем библиотеку:

Затем объявляем переменную и присваиваем ей тип нужного приложения:

Sub OpenWord()
    Dim objWrdApp As Word.Application
    Set objWrdApp = New Word.Application
    objWrdApp.Visible = True
End Sub

Если теперь в редакторе, внутри этой процедуры в любом месте ниже объявления переменной набрать objWrdApp и точку, то сразу после ввода точки выпадет меню, в котором будут перечислены все доступные методы и свойства этого приложения.

Так же можно нажать F2 и через поиск найти Word и просмотреть все методы и свойства данного приложения.

Метод установки ссылки на библиотеку приложения через Tools-References называют еще ранним связыванием. Подобный метод позволяет создать ссылку на приложение быстрее и, как описано выше, предоставляет разработчику доступ к визуальному отображению свойств и методов объекта. Но есть существенный минус: если в своем коде Вы установите ссылку на Word 12 Object Libbary(Word 2007), то на ПК с установленным Word 2003 получите ошибку MISSING, т.к. Word 2003 относится к библиотеке Word 11 Object Libbary. Подробнее можно прочитать в статье Ошибка — Cant find project or library.
Метод же CreateObject еще называется методом позднего связывания. Применяя его не возникнет проблем с MISSING, очень часто возникающих при раннем связывании. Поэтому я рекомендовал бы при разработке использовать раннее связывание для удобства использования свойств и методов(если Вы их не знаете), а перед распространением приложения в коде заменить все именованные константы(типа wdLine) на числовые константы(для wdLine это 5) и применить позднее связывание. Посмотреть числовое значение константы можно просто записав её в коде, начать выполнение кода через F8 и навести курсор мыши на эту константу. Всплывающая подсказка покажет числовое значение. Так же можно отобразить окно Immediate(View -Immediate Window или сочетание клавиш Ctrl+G), записать вопросительный знак и вставить эту константу и нажать Enter:
?wdLine
ниже будет выведено числовое представление этой константы.
А заменять эти константы их числовыми значениями в случае с поздним связыванием необходимо, т.к. Excel не знает их значений.
Попробую пояснить поподробнее про эти константы и почему их надо заменять какими-то числами: при подключении библиотеки Wordа(Word 12 Object Libbary) мы так же подключаем и все свойства, методы и константы, которые доступны из Wordа. И их использование напрямую становится доступно из Excel и мы можем смело написать что-то вроде wbLine и Excel поймет эту константу. При позднем же связывании мы уже не подключаем библиотеки Word(во избежание ошибок совместимости) и как следствие - методы, свойства и константы Wordа для Excel становятся чем-то неизвестным и не документированным и мы получим ошибку "Variable not defined"(если включена директива Option Explicit) при попытке назначить свойство через wdLine. Если же Option Explicit не включена - то хоть ошибки не будет, но и код будет работать неверно, т.к. для неизвестной для Excel переменной wbLine будет назначено значение 0(Empty). Поэтому и надо все константы другого приложения заменять их числовыми значениями.

Главная ошибка новичка
И хочу так же упомянуть про ошибку, которую очень часто совершают при обращении к одному приложению из другого. Допустим, необходимо скопировать из Word все данные в Excel. Часто начинающие делают это так:

Sub OpenWord()
    Dim objWrdApp As Object, objWrdDoc As Object
    'создаем новое приложение Word
    Set objWrdApp = CreateObject("Word.Application")
    'Можно так же сделать приложение Word видимым. По умолчанию открывается в скрытом режиме
    'objWrdApp.Visible = True
    'открываем документ Word - документ "Doc1.doc" должен существовать
    Set objWrdDoc = objWrdApp.Documents.Open("C:\Doc1.doc")
    'Копируем из Word все данные, обращаясь к объекту Range документа
    Range.Copy
    'вставляем скопированное в ячейку А1 активного листа Excel
    ActiveSheet.Paste
    'закрываем документ Word без сохранения
    objWrdDoc.Close False
    'закрываем приложение Word
    objWrdApp.Quit
    'очищаем переменные Word - обязательно!
    Set objWrdDoc = Nothing: Set objWrdApp = Nothing
End Sub

На строке Range.Copy обязательно получите ошибку от VBA, указывающую, что нужен аргумент для объекта. Можно попробовать добавить этот аргумент: Range(1).Copy. Но все равно получим ошибку. Можно, конечно, указать даже ячейки: Range("A1").Copy. Но это приведет к тому, что скопирована будет ячейка А1 активного листа Excel.
Все дело в том, что мы хотим скопировать данные из Word-а, выполняя при этом код из Excel. А у Excel тоже есть объект Range с другими аргументами. И если не указать какому приложению, листу или документу принадлежит Range, то по умолчанию он будет отнесен к тому приложению, из которого выполняется код. Т.е. к Excel. Если совсем кратко об этом - всегда надо указывать какому приложению или объекту принадлежит используемый объект или свойство. Правильно код должен выглядеть так:

Sub OpenWord()
    Dim objWrdApp As Object, objWrdDoc As Object
    'создаем новое приложение Word
    Set objWrdApp = CreateObject("Word.Application")
    'Можно так же сделать приложение Word видимым. По умолчанию открывается в скрытом режиме
    'objWrdApp.Visible = True
    'открываем документ Word - документ "Doc1.doc" должен существовать
    Set objWrdDoc = objWrdApp.Documents.Open("C:\Doc1.doc")
    'Копируем из Word все данные, обращаясь к объекту Range документа
    'при этом перед Range явно указываем откуда его брать - из документа Word -objWrdDoc("C:\Doc1.doc")
    objWrdDoc.Range.Copy
    'вставляем скопированное из Word в активную ячейку активного листа Excel
    ActiveSheet.Paste
    'закрываем документ Word без сохранения
    objWrdDoc.Close False
    'закрываем приложение Word
    objWrdApp.Quit
    'очищаем переменные Word - обязательно!
    Set objWrdDoc = Nothing: Set objWrdApp = Nothing
End Sub

Вместо Range ту же ошибку делают и с Selection(потому что Selection часто присутствует в записанных макрорекордером макросах), т.к. этот объект есть и в Excel и в Word и без явного указания приложения будет относится к приложению, в котором записано.


В приложенном файле код немного отличается от представленных выше - в нем можно посмотреть как вставить текст из ячеек в определенные(созданные заранее) закладки Word-а. Это удобно для создания бланков в Word и заполнения их через Excel
Скачать пример:

  Tips_Macro_OpenWord.xls (49,5 KiB, 6 706 скачиваний)


А в архиве ниже - практически готовое решение заполнения всевозможных бланков Word из Excel. Как это работает. У нас есть таблица Excel с данными для заполнения бланков заявлений на пособия:
Исходная таблица
Обращаю внимание, что в первой строке расположены метки. Они нужны для того, чтобы код мог понять значения какого столбца в какое место шаблона Word должны попасть. А в самом шаблоне Word мы должны проставить эти самые метки:
Шаблон Word с метками
Фигурные скобки сделаны для того, чтобы код 100% искал и заменял только метку в шаблоне, исключая при этом замену случайного текста вне скобок(ведь слово "Должность" может встречаться и само по себе).
А здесь я схематично привел то, как будут происходить замены:
Схема замен
Сначала программа создаст новую папку, в которую и будет сохранять создаваемые файлы(имя папки состоит из даты и времени запуска кода). Далее программа циклом пройдется по каждой строке таблицы, создаст на основании шаблона Word("Шаблон.doc") новый файл для этой строки, заполнит этот шаблона данными на основании меток, и сохранит созданный файл под новым именем. Сам файл шаблона при этом не изменяется - все метки в нем сохраняются как были настроены до запуска кода. Конкретно в приложенном коде значение для имени нового файла берется из первого столбца "ФИО с инициалами". Но это можно изменить в коде при необходимости. Делается это в этой строке:

'считываем фамилию с инициалами
sWDDocName = .Cells(lr, 1).Value

Что еще важно: файл шаблона Word должен находиться в той же папке, что и файл с кодом. Название файла в приложенном к статье файле должно быть "Шаблон.doc". Но его так же можно изменить, не забыв изменив его в коде в этой строке:

'имя шаблона Word с основным текстом и метками
Const sWDTmpl As String = "Шаблон.doc"

В общем-то, если хоть чуть-чуть разбираетесь, то поменять можно многое. А для тех, кто не разбирается достаточно будет просто создавать метки в файле Word и обозначать ими столбца в таблице Excel. Количество столбцов и строк в таблице код определяет автоматически и при изменении размеров таблицы ничего изменять не надо. Главное, чтобы метки находились в первой строке, вторая строка - заголовок(необязательно), а с третьей строки начинаются данные, которые и используются для наполнения шаблонов.
Скачать пример:

  Автосоздание бланков Word из таблицы Excel.zip (37,6 KiB, 1 865 скачиваний)

Примеры работы с тем же Outlook можно посмотреть в моих статьях:
Как отправить письмо из Excel?
Сохранить вложения из Outlook в указанную папку


Статья помогла? Поделись ссылкой с друзьями!
  Плейлист   Видеоуроки

Поиск по меткам

Access apple watch Multex Power Query и Power BI VBA управление кодами Бесплатные надстройки Дата и время Записки ИП Надстройки Печать Политика Конфиденциальности Почта Программы Работа с приложениями Разработка приложений Росстат Тренинги и вебинары Финансовые Форматирование Функции Excel акции MulTEx ссылки статистика
Обсуждение: 59 комментариев
  1. Dimodimka:

    что делать если VBA не распознает objWrdDoc.bookmarks (обращение к закладке). Вообще можете подсказать литературу где можно поподробней прочитать к обращению через Excel к закладкам Word? Может там есть какая то особенность создания этих закладок?

  2. Dimodimka, что скрывается под понятием "не распознает"? У меня распознает. Может ошибку какую пишет?-тогда укажите какую именно. Закладки в документе есть? Как именно к ним обращаетесь? Может Вы обращаетесь к закладке с именем, которого нет в закладках? В общем опишите свои действия - явно что-то Вы делаете не так или что-то не сделали.
    Что касаемо особенностей создания: особенность одна - создали закладку, присвоили ей имя и к этому имени в коде и обращаетесь. Все.

  3. Dimodimka:

    Создал закладку в Word-овском файле "ТКП шаблон" (С:\Шаблоны\ТКП Шаблон). Закладку назвал "DataPodgotovki". Хочу чтобы при запуске макроса запускался документ "ТКП шаблон" в место закладки вставлялся текст расположенный в Excel\ лист временный\ячейка B4 и сохранялся как "ТКП Готов" в папке из которой был вызван. Получилось следующее:

    Sub OpenWord()
        Dim objWrdApp As Object, objWrdDoc As Object
        'создаем новое приложение Word.
     
        Dim SaveAsName As String
        SaveAsName = ThisWorkbook.Path & "" & "ТКП Готово" & ".doc"
     
        Set objWrdApp = CreateObject("Word.Application")
        objWrdApp.Visible = True
     
        'открываем документ Word - документ "C:ШаблоныТКП шаблон.doc" должен существовать
        Set objWrdDoc = objWrdApp.Documents.Open("C:ШаблоныТКП шаблон.doc")
        objWrdApp.Visible = True
     
        'Копируем из Excel
        Range("B4").Copy
     
        'вставляем скопированные ячейки  в объект Закладки Word-а
        objWrdDoc.bookmarks("DataPodgotovki").Text = Range("B4")
        'закрываем документ Word с сохранением
     
        objWrdApp.SaveAs Filename:=SaveAsName
        'очищаем переменные Word - обязательно!
     
        Set objWrdDoc = Nothing: Set objWrdApp = Nothing
     
    End Sub

    Запускаю макрос. Выводит ошибку Run time error "438". Видно что ошибка в строчке objWrdDoc.bookmarks("DataPodgotovki").Text = Range("B4")

  4. Dimodimka:

    Может причина в том что у меня подключена библиотека Microsoft Word 11.0 Object library. Можно ли скачать и установить более новые версии, например 14.0. Такое ощущение, что макрос не востпринимает Bookmarks как часть команды

  5. Вы плохо ориентирутесь в объектных моделях приложений. Если бы проблема была в библиотеке - то она возникла бы еще на строке CreateObject.

    Попробуйте заменить строку:

    sTxt = Range("B4").Value

    на такую:

    objWrdDoc.bookmarks("DataPodgotovki").Text = sTxt

    А еще лучше создайте новую переменную:
    Dim sTxt as string
    вместо Range("B4").Copy пишите:

    sTxt = Range("B4").Value

    а затем уже:

    objWrdDoc.bookmarks("DataPodgotovki").Text = sTxt

    Ячейка Range("B4") не должна содержать ошиочных значений.

  6. Dimodimka:

    Получилось так:

    Sub OpenWord()
        Dim objWrdApp As Object, objWrdDoc As Object
        Dim sTxt As String
        Dim SaveAsName As String
        SaveAsName = ThisWorkbook.Path & "" & "ТКП Готово" & ".doc"  
        Set objWrdApp = CreateObject("Word.Application")
        objWrdApp.Visible = True
        Set objWrdDoc = objWrdApp.Documents.Open("C:ШаблоныТКП шаблон.doc")
        objWrdApp.Visible = True
        Worksheets("временный").Activate
        sTxt = Range("B4").Value
        objWrdDoc.bookmarks("DataPodgotovki").Text = sTxt  
        objWrdApp.SaveAs Filename:=SaveAsName    
        Set objWrdDoc = Nothing: Set objWrdApp = Nothing
     
    End Sub

    Проблема не решилась - та же ошибка. В той же строке.

  7. Sub OpenWord()
     Dim objWrdApp As Object, objWrdDoc As Object
     Dim sTxt As String
     Dim SaveAsName As String
     SaveAsName = ThisWorkbook.Path & "" & "ТКП Готово.doc"
     sTxt =  Worksheets("временный").Range("B4").Value
     Set objWrdApp = CreateObject("Word.Application")
     objWrdApp.Visible = True
     Set objWrdDoc = objWrdApp.Documents.Open("C:ШаблоныТКП шаблон.doc")
     objWrdApp.Visible = True
     objWrdDoc.bookmarks("DataPodgotovki").Text = sTxt
     objWrdApp.SaveAs Filename:=SaveAsName
     Set objWrdDoc = Nothing: Set objWrdApp = Nothing
     
    End Sub

    А вообще неплохо бы ознакомиться с Вашими примерами наглядно(пример файла Word и Excel). У меня проблем с обращением к закладкам нет. Ошибка указывает на то, что свойство не поддерживается объектом. Вы точно закладку создали? Именно закладку, не ссылку, не надпись и т.п.?

  8. Dimodimka:

    Очень оперативно работаете, мне это нравиться.

    Сделал все как написали, запускаю макрос, Вордовский файл "ТКП шаблон" открывает, а потом ошибку "438" выдает, нажимаю "debug", та же строка выделяется:
    objWrdDoc.bookmarks("DataPodgotovki").Text = sTxt

  9. Dimodimka:

    В ворде Вставка-Закладка - там то вряд ля я что то напутал

  10. Ну и как Вам помочь? Я в предыдущем сообщении даже не намекнул - прямо написал, что неплохо ознакомиться с Вашими файлами. Сидеть здесь и доказывать, что это работает у всех, кроме Вас смысла без файлов не вижу.
    Если не знаете мою почту: The-Prist@yandex.ru

Поделитесь своим мнением

Комментарии, не имеющие отношения к комментируемой статье, могут быть удалены без уведомления и объяснения причин. Если есть вопрос по личной проблеме - добро пожаловать на Форум


Для оформления сообщений Вы можете использовать следующие тэги:
<a href="" title=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <q cite=""> <s> <strike> <strong>

Тренинги

Заказать
Юридическая информация

Использование материалов сайта

Политика Конфиденциальности

ИП Щербаков Дмитрий Валентинович
ОГРНИП: 318502700083307
ИНН: 504013350772

Наши партнеры

Перейти

Счетчики

Рейтинг@Mail.ru Яндекс.Метрика
© 2024 Excel для всех   Войти