Ошибка: Невозможно получить свойство Item класса Buttons (VBA EXCEL 2003)

[Ratibor Redoran]

Доброго времени суток!

Написал скрипт для создания кнопки на активном листе экселевской книги (при выполнении условия):

Код: (vb)

Public Sub CreateButton()
  c = ActiveCell.Column
  r = ActiveCell.Row

  ActiveSheet.Rows("1:1").RowHeight = 30

  ActiveSheet.Buttons.Add(2, 2, 120, 25).Select
  Selection.OnAction = "Saving"
  Application.CommandBars("Forms").Visible = False
  Selection.Characters.Text = "Сохранить"
  
  With Selection.Characters(Start:=1, Length:=12).Font
    .Name = "Arial Cyr"
    .Size = 14
  End With

  ActiveSheet.Cells(r, c).Select
End Sub

Public Sub DeleteButtons()
  For i = 1 To ActiveSheet.Buttons.Count
    'Строка кода, в которой обнаруживается ошибка
    If ActiveSheet.Buttons.Item(i).Caption = "Сохранить" Then '***
      ActiveSheet.Buttons.Item(i).Delete
    End If
  Next
End Sub

Public Sub Workbook_BeforeClose(Cancel As Boolean)
  DeleteButtons
End Sub

Public Sub Workbook_Open()
  If (/* Здесь проверяется условие для создания кнопки */) Then
    ButtonCreate
  End If
End Sub

Но на строке кода c комментарием "***" возникает сообщение об ошибке:
Run-time error '1004'
Невозможно получить свойство Item класса Buttons

Не могли бы вы подсказать, почему отсутствует свойство Item, если значение свойства Count указывает на то, что кнопки имеются?

[Дмитрий Щербаков(The_Prist)]

У меня проблема не повторяется. И свойство получено, и кнопка удалена. Возможно, это проблемы файла. Можете приложить файл, в котором не работает? Или не работает в любом файле, даже только что созданном?

[Ratibor Redoran]

У меня проблема не повторяется. И свойство получено, и кнопка удалена. Возможно, это проблемы файла. Можете приложить файл, в котором не работает? Или не работает в любом файле, даже только что созданном?

Создал пустой файл - все работает...

Кажется начинаю понимать: если скопировать созданную кнопку (Ctrl-C -> Ctrl-V) несколько раз, то можно заметить (в отладчике), что после удаления кнопки ссылка на Item(i) уже отсутствует и поэтому возникает сообщение об ошибке. Надо заменить код

Код: (vb)

    If ActiveSheet.Buttons.Item(i).Caption = "Сохранить" Then '***  
      ActiveSheet.Buttons.Item(i).Delete  

на

Код: (vb)

    If ActiveSheet.Buttons.Item(1).Caption = "Сохранить" Then '***  
      ActiveSheet.Buttons.Item(1).Delete  

вроде все заработало, спасибо!

[Дмитрий Щербаков(The_Prist)]

Тогда можно делать так(указывать всегда 1 тоже не очень правильно):

Код: (vb)

Public Sub DeleteButtons()
dim x
  For each x in ActiveSheet.Buttons
    'Строка кода, в которой обнаруживается ошибка  
    If x.Caption = "Сохранить" Then '***  
      x.Delete  
    End If  
  Next  
End Sub

или использовать цикл с конца:

Код: (vb)

For i = ActiveSheet.Buttons.Count to 1 step -1